Tekstfuncties

Zodra je bezig bent met gegevens in overzichtelijke lijsten te zetten, zal je geregeld tekstfuncties nodig hebben, bv. om elke naam met een hoofdletter te laten beginnen.

Kijk je op het lint bij Formules – Tekst, dan krijg je een overzicht van alle mogelijke tekstfuncties.
Hieronder de meest gebruikte. De basistekst in de formule is ofwel een celadres ofwel letterlijke tekst tussen aanhalingstekens.

Toon de tekst anders:

=BEGINLETTERS(tekst): zet de eerste letter van elk woord in tekst om in een hoofdletter en de rest in kleine letters
=KLEINE.LETTERS(tekst): zet tekst om in kleine letters
=HOOFDLETTERS(tekst): zet tekst om in hoofdletters
=EURO(getal): converteert een getal naar tekst met vooraan het euroteken
=TEKST(waarde;notatie): converteert een waarde naar tekst in een specifieke getalnotatie

Pas de tekst aan:

=DEEL(tekst;begin;aantal): geeft aantal tekens uit tekst, beginnend op positie begin
=HERHALING(tekst;aantal): herhaalt een tekst een aantal keren
=LINKS(tekst;aantal): geeft de eerste aantal tekens van tekst
=RECHTS(tekst;aantal): geeft de laatste aantal tekens uit tekst
=SPATIES.WISSEN(tekst): verwijdert de overbodige spaties uit tekst; de enkele spatie tussen woorden blijft staan
=SUBSTITUEREN(tekst;oud_tekst;nieuw_tekst): vervangt oud_tekst door nieuw_tekst in tekst
=VERVANGEN(tekst;begin;aantal;nieuw_tekst): vervangt aantal tekens vanaf positie begin binnen tekst door nieuw_tekst
=VIND.ALLES(zoeken;tekst): geeft de beginpositie van tekenreeks zoeken in tekst (er wordt onderscheid gemaakt tussen hoofdletters en kleine letters)
=VIND.SPEC(zoeken;tekst): geeft de beginpositie van tekenreeks zoeken in tekst (er wordt geen onderscheid gemaakt tussen hoofdletters en kleine letters)

En nog een eigenschap:

=LENGTE(tekst): bepaalt het aantal tekens in de tekenreeks tekst

In de laatste versie van Excel zijn er nog enkele interessante bijgekomen:

=TEKST.VOOR(tekst;karakter;n): geeft het deel uit de tekst links van het n-de voorkomen van het opgegeven karakter tussen aanhalingstekens
=TEKST.NA(tekst;karakter;n): geeft het deel uit de tekst rechts van het n-de voorkomen van het opgegeven karakter tussen aanhalingstekens
=TEKST.SPLITSEN(tekst;karakter): splitst de tekst aan het opgegeven karakter en verdeelt die over meer cellen. Je kan ook meer dan één scheidingsteken opgeven tussen {}

DOE Test de tekstfuncties uit

Typ in cel A1: Vandaag gaan we hard werken
Zet in A2 de formule =KLEINE.LETTERS(A1) en bestudeer het resultaat.
Zet in A3 de formule =HOOFDLETTERS(A1) en bestudeer het resultaat.
Zet in A4 de formule =BEGINLETTERS(A1) en bestudeer het resultaat.
Zet in A5 de formule =HOOFDLETTERS(hallo) en je krijgt een foutmelding. Voeg aanhalingstekens toe en dan werkt het: =HOOFDLETTERS("hallo")

We kunnen ook enkele tekens uit het geheel halen. Je moet er dan wel rekening mee houden dat een spatie ook een teken is, die moet je dus meetellen.

Zet in A6 de formule =LINKS(A1;3). Het resultaat zijn de eerste drie tekens van de tekst in A1.
Zet in A7 de formule =RECHTS(A1;6). Het resultaat zijn de laatste 6 tekens van de tekst in A1.
In A8 komt de formule =DEEL(A1;9;4). Het resultaat zijn 4 tekens vanaf positie 9 in de tekst in A1.
Je kan ook meten hoeveel tekens de tekst bevat. bv: =LENGTE(A1) leert je dat de tekst in A1 uit 27 tekens bestaat en =LENGTE(" ") leert je dat een spatie 1 teken lang is.

Ander voorbeeld: haal een deel uit een tekst. In dit geval: haal de voornaam, dwz het deel na de spatie (" "+1) uit een volledige naam.

Typ in B11 je familienaam en voornaam met een spatie tussen.
Zet in B12 de formule =DEEL(B11;VIND.ALLES(" ";B11)+1;LENGTE(B11))
Zit er een spatie in je familienaam? Zorg dat vind.alles NA die spatie begint te zoeken door als derde argument in die functie een verdere positie in de tekst op te geven.
Beetje ingewikkeld? Gebruik de nieuwe functie =TEKST.NA(B11;" ";1) om het deel na de eerste spatie uit je naam te halen of =TEKST.NA(B11;" ";-1) voor het deel na de laatste spatie.
In B13 komt als formule ="Die "&B12&" toch!"
Tenslotte in B14: =HOOFDLETTERS(B13)

Je kan ook de drie formules samenvatten in één lange formule maar dat wordt wel onoverzichtelijk ...

DOE Voeg tekst samen

Voeg een werkblad toe en typ opnieuw in cel A1 (of kopieer): Vandaag gaan we hard werken
Typ in A2 je voornaam en in A3 je familienaam.
Om één geheel te maken van je voornaam en je familienaam zet je ze samen in een formule met een spatie tussen.
- In A4 komt de formule met de operator: =A2 & " " & A3 of =A2&" "&A3, met of zonder spaties rond de operator geeft hetzelfde resultaat.
- In A5 zetten we de formule met de functie: =TEKST.SAMENV(A2;" ";A3)
Zoals je aan de spatie ziet, kan je ook letterlijke tekst en een verwijzing samen in een formule zetten.
- Zet in A6 de formule ="Hallo "&A1 of =TEKST.SAMENV("Hallo ";A1), naar keuze.
- Grammaticaal klopt die zin niet: er komt een hoofdletter in van de zin in A1 en dat mag niet. Dus moeten we functie KLEINE.LETTERS() erbij halen.
- Ofwel wordt het ="Hallo "&KLEINE.LETTERS(A1)
- Ofwel =TEKST.SAMENV("Hallo ";KLEINE.LETTERS(A1))

DOE fatsoeneer de adressenlijst

Download en open tekst.xlsx, blad adrLijst.
De sekse moet een hoofdletter "M" of "V" zijn.
- Voeg een kolom toe rechts van kolom C en sleep de titel in C1 naar D1.
- Maak de correcte ALS-formule in D2 en kopieer naar beneden.
- Verberg kolom C
De woonplaats moet beginnen met een hoofdletter en bestaat verder uit kleine letters. Volg een gelijkaardige werkwijze als daarnet.

DOE Maak de oefening tekstfuncties